patrickfav/slf4j-timber

apply from: "$rootDir/gradle/common-build.gradle"

buildscript {
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.1.2'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.1'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.0'
        classpath 'de.mobilej.unmock:UnMockPlugin:0.6.4'
        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.8.2'
        classpath 'com.dicedmelon.gradle:jacoco-android:0.1.2'
    }
}

allprojects {
    repositories {
        google()
        jcenter()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

ext {
    versionNameLib = "1.0.1"
    versionNameApp = "v$versionNameLib"
    versionCode = getCiBuildNumber()
    versionNameDep = "0.+"

    compileSdkVersion = 27
    buildToolsVersion = "27.0.3"
    targetSdkVersion = 27
    minSdkVersion = 14
    javaVersion = JavaVersion.VERSION_1_8

    dependencies = [
            junit   : '4.12',
            timber  : '4.6.1',
            slf4j   : '1.7.25'
    ]
}

//disables Java8 javadoc lint which is way to restrictive
if (JavaVersion.current().isJava8Compatible()) {
    allprojects {
        tasks.withType(Javadoc) {
            options.addStringOption('Xdoclint:none', '-quiet')
        }
    }
}

//this defines an Android compatible provided scope, see: https://sinking.in/blog/provided-scope-in-gradle/
configurations {
    provided {
        dependencies.all { dep ->
            configurations.default.exclude group: dep.group, module: dep.name
        }
    }
    compile.extendsFrom provided
}

task publishLibs(dependsOn: [':clean', 'hood-core:assemble', ':hood-core:install', ':hood-extended:install', ':hood-core:bintrayUpload']) {
    doLast {
        println "published"
    }
}