trusona/trusona-server-sdk-java

task sourceJar(type: Jar) {
  from sourceSets.main.allJava
  classifier "sources"
}

javadoc {
  source = sourceSets.main.allJava
  classpath = configurations.compileClasspath
  title = "Trusona SDK"
  options {
    memberLevel = JavadocMemberLevel.PUBLIC
    source = "1.8"
  }
}

task javadocZip(type: Zip) {
  dependsOn javadoc

  from "${javadoc.destinationDir}/.."
  into "${project.name}-${project.version}"
  archiveName = "${project.name}-${project.version}.zip"
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier = 'javadoc'
  from javadoc.destinationDir
}

artifacts {
  archives javadocJar, javadocZip, sourceJar
}

publishing {
  publications {
    mavenJava(MavenPublication) {
      from components.java

      artifact sourceJar
      artifact javadocZip
      artifact javadocJar
    }
  }
}

signing {
  sign publishing.publications.mavenJava
  sign configurations.archives
}

dependencies {
  implementation project(":trusona-sdk-http")
  implementation project(":trusona-sdk-resources")

  testImplementation "org.apache.groovy:groovy-all:4.0.21"
  testImplementation "org.spockframework:spock-core:2.3-groovy-4.0"
  testImplementation "com.squareup.okhttp3:mockwebserver:4.12.0"
  testImplementation "ch.qos.logback:logback-classic:1.5.6"

  spotbugsPlugins "com.h3xstream.findsecbugs:findsecbugs-plugin:1.13.0"
}